Accessファイル選択ダイアログ（Microsoft Office関連） | 小技集

Accessファイル選択ダイアログ

トップ > 小技集 > （Microsoft Office関連）Accessファイル選択ダイアログ

Access2003でファイル選択ダイアログを表示する方法をご紹介します。

　お急ぎの場合は、完成したmdbファイルをこちらからダウンロードできます。

　Accessフォームのテキストボックスにファイル名を入力させるような場合に、ファイル選択ダイアログを表示できると操作性が向上しますね。
　ここでは、Access 2003でファイル選択ダイアログを表示するためのVBAコードを紹介します。

　まずは、下のような簡単なフォームを作成しましょう。

　このフォームのクラスモジュールに、ボタンのイベントハンドラを記述します。

Private Sub Button1_Click()
    ' ボタン押下前にテキストボックスに入力されていた
    ' ファイル名を保持しておく
    Dim OriginalFileName As String
    If Not IsNull(Form_FORM1.TextBox1.Value) Then
        OriginalFileName = Form_FORM1.TextBox1.Value
    End If
    
    ' ファイル選択ダイアログ表示
    Form_FORM1.TextBox1.Value = FileSelect()
    
    ' ファイル選択ダイアログでキャンセルボタンが押されたら、
    ' 初めに保持していたファイル名を戻す
    If IsNull(Form_FORM1.TextBox1.Value) Then
        Form_FORM1.TextBox1.Value = OriginalFileName
    End If
End Sub

　このイベントハンドラ内で呼び出す、ファイル選択ダイアログを表示する関数FileSelect( )は、いろいろなフォームから呼ばれる可能性があるため、共通部品として標準モジュールに記述します。

Function FileSelect()
On Error GoTo ErrorHandler

    Dim SelectedFile As Variant
    
    With Application.FileDialog(msoFileDialogFilePicker)
        .Title = "ファイル選択"
        .Filters.Add "すべてのファイル", "*.*"
        .Filters.Add "テキストファイル", "*.txt"
        .Filters.Add "TSVファイル", "*.tsv"
        .Filters.Add "EXCELファイル", "*.xls"
        .AllowMultiSelect = False
        .InitialFileName = CurrentProject.Path
        
        If .Show = -1 Then
        For Each SelectedFile In .SelectedItems
            FileSelect = SelectedFile
            Next
        End If
    End With
Exit Function

ErrorHandler:
    MsgBox Err.Description, vbCritical
    End
End Function

　（参考）Visual Basic Editorのオブジェクトエクスプローラ

　このコードを正しく動作させるためには、参照設定が必要です。
　FileSelect( )関数のApplication.FileDialogの行を入力するとき、下記のようなポップアップが表示されたら「はい」を押して参照設定を追加してください。

　ポップアップが表示されない場合は、Visual Basic Editorのツール→参照設定で「Microsoft Office 11.0 Object Library」を追加してください。

トップ > 小技集 > （Microsoft Office関連）Accessファイル選択ダイアログ

トップ | このサイトについて | 管理者へメール | サイトマップ